start command: fix default value for port

Defaulting the port to "8080" at the `command-line' level breaks
customization via `pollen.rkt'.

pollen/private/command.rkt

@@ -182,13 +182,13 @@ version                print the version" (current-server-port) (make-publish-di
      #:once-each
      [("--launch" "-l") "Launch browser after start" (set! launch-wanted #t)]
      [("--local") "Restrict access to localhost" (set! localhost-wanted #t)]
-     #:args ([dir (current-directory)] [port "8080"])
+     #:args ([dir (current-directory)] [port #f])
      (define parsed-dir
        (path->directory-path (normalize-path (very-nice-path dir))))
      (unless (directory-exists? parsed-dir)
        (error (format "~a is not a directory" parsed-dir)))
 
-     (define parsed-port (string->number port))
+     (define parsed-port (and port (string->number port)))
      (when (and parsed-port (not (exact-positive-integer? parsed-port)))
        (error (format "~a is not a valid port number" parsed-port)))
      (values parsed-dir parsed-port)))

pollen/test/data/project-port/hello.txt.pp

@@ -0,0 +1,3 @@
+#lang pollen
+
+Hello!

pollen/test/data/project-port/pollen.rkt

@@ -0,0 +1,6 @@
+#lang racket/base
+
+(module setup racket/base
+  (provide (all-defined-out))
+  (define project-server-port
+    9876))

pollen/test/test-project-port.rkt

@@ -0,0 +1,36 @@
+#lang racket/base
+
+(require rackunit
+         racket/port
+         racket/runtime-path)
+
+(define-runtime-path project-port-dir "data/project-port")
+
+(define thd #f)
+(define-values (in out) (make-pipe))
+(parameterize ([exit-handler (lambda (code)
+                               (fail (format "abnormal exit from raco command~n  code: ~a" code))
+                               (kill-thread thd))])
+  (set! thd
+        (parameterize ([current-output-port out]
+                       [current-error-port out]
+                       [current-directory project-port-dir]
+                       [current-command-line-arguments (vector "start")])
+          (thread
+           (lambda ()
+             (dynamic-require '(submod pollen/private/command raco) #f)))))
+
+  (dynamic-wind
+    void
+    (lambda ()
+      (sync
+       (handle-evt
+        (regexp-match-evt #rx"project server is http://localhost:9876" in)
+        void)
+       (handle-evt
+        (alarm-evt (+ (current-inexact-milliseconds) 5000))
+        (lambda (_)
+          (fail "timed out while waiting for server to start")))))
+    (lambda ()
+      (break-thread thd)
+      (thread-wait thd))))